Can you post the link to a public copy of your simulation so that we can investigate?

Thanks.

https://easyeda.com/editor#id=l93lDVP6o

The problem is that apart from the passive components, none of the components you have chosen from the SHIFT+F library have spice simulation models associated with them.

There is a spice model available for the AD8615 but it has had to be modified to run in ngspice (the simulation engine used by EasyEDA):

* Analog Devices AD8615 20MHz CMOS rail to rail input/output AD8615 opamp SPICE Macro-model
* Edited to run in ngspice by
* Signality.co.uk 160724
* Removed comma characters in POLY descriptions and model parameter lists.
*
* AD8615 SPICE Macro-model
* Description: Amplifier
* Generic Desc: 2.7/5V, CMOS, OP, Fast, RRIO, 1X
* Developed by: VW ADSJ
* Revision History: 08/10/2012 - Updated to new header style
* 2.0 (02/2010)
* Copyright 2010, 2012 by Analog Devices
*
* Refer to http://www.analog.com/Analog_Root/static/techSupport/designTools/spiceModels/license/spice_general.html for License Statement. Use of this model
* indicates your acceptance of the terms and provisions in the License Statement.
*
* BEGIN Notes: VSY=5V, T=25°C
*
* Not Modeled:
*
* Parameters modeled include:
*
* END Notes
*
* Node Assignments
* noninverting input
* | inverting input
* | | positive supply
* | | | negative supply
* | | | | output
* | | | | |
* | | | | |
.SUBCKT AD8615 1 2 99 50 45
*
* INPUT STAGE
*
M1 4 7 8 8 PIX L=1E-6 W=3.64E-04
M2 6 2 8 8 PIX L=1E-6 W=3.64E-04
M3 14 7 18 18 NIX L=1E-6 W=1.44E-04
M4 16 2 18 18 NIX L=1E-6 W=1.44E-04
RD1 4 50 1.33E+04
RD2 6 50 1.33E+04
RD3 99 14 1.33E+04
RD4 99 16 1.33E+04
C1 4 6 5.95E-14
C2 14 16 5.95E-14
I1 99 8 3.65E-05
I2 18 50 3.65E-05
V1 99 9 -1.087E+01
V2 19 50 1.280E-01
D1 8 9 DX
D2 19 18 DX
EOS 7 1 POLY(4) (73 98) (22 98) (81 98) (83 98) 2.30E-05 1 1 1 1
IOS 1 2 5.00E-14
*
*CMRR
*
E1 72 98 POLY(2) (1 98) (2 98) 0 1.507E-03 1.507E-03
R10 72 73 1.061E+01
R20 73 98 8.842E-02
C10 72 73 1.00E-06
*
* PSRR
*
EPSY 21 98 POLY(1) (99 50) -0.3750E+00 0.750E-01
RPS1 21 22 7.9577E+00
RPS2 22 98 1.061E-02
CPS1 21 22 1.00E-06
*
* VOLTAGE NOISE
*
VN1 80 98 0
RN1 80 98 16.45E-3
HN 81 98 VN1 4.3E+00
RN2 81 98 1
*
* FLICKER NOISE
*
DFN 82 98 DNOISE
VFN 82 98 DC 0.6551
HFN 83 98 POLY(1) VFN 1.00E-03 1.00E+00
RFN 83 98 1
*
* INTERNAL VOLTAGE REFERENCE
*
EREF 98 0 POLY(2) (99 0) (50 0) 0 0.5 0.5
GSY 99 50 POLY(1) (99 50) 8.786E-04 1.33E-05
EVP 97 98 (99 50) 0.5
EVN 51 98 (50 99) 0.5
*
* GAIN STAGE
*
G1 98 30 POLY(2) (4 6) (14 16) 0 3.710E-03 3.710E-03
R1 30 98 1.00E+06
RZ 45 31 5.321E+01
CF 30 31 2.975E-10
V3 32 30 1.50E+00
V4 30 33 1.08E+00
D3 32 97 DX
D4 51 33 DX
*
* OUTPUT STAGE
*
M5 45 46 99 99 POX L=1E-6 W=1.48E-03
M6 45 47 50 50 NOX L=1E-6 W=9.26E-03
EG1 99 46 POLY(1) (98 30) 8.250E-01 1
EG2 47 50 POLY(1) (30 98) 7.000E-01 1

*
* MODELS
*
.MODEL POX PMOS (LEVEL=2 KP=4.00E-05 VTO=-0.7 LAMBDA=0.047 RD=0)
.MODEL NOX NMOS (LEVEL=2 KP=1.00E-05 VTO=+0.6 LAMBDA=0.022 RD=0)
.MODEL PIX PMOS (LEVEL=2 KP=1.50E-05 VTO=-0.5 LAMBDA=0.047)
.MODEL NIX NMOS (LEVEL=2 KP=4.00E-05 VTO=0.5 LAMBDA=0.022)
.MODEL DX D(IS=1E-14 RS=0.1)
.MODEL DNOISE D(IS=1E-14 RS=0 KF=4.83E-11)
*.MODEL DNOISE D(IS=1E-14 RS=0 KF=3.43E-11)
*
*
.ENDS AD8615

There is no publically available spice model for the ADG633 Triple SPDT switch but it is possible to model the switches at a basic level by using the Voltage Controlled Switch from the EasyEDA Libs.

There are also no models available for the laser module or photodiode but it is possible to behaviourally model them.

Example simulations using the EasyEDA PHOTODIODE_EE spice model and the modified AD8615 are shown here:

https://easyeda.com/andyfierman/Demonstrating_the_EasyEDA_generic_photodiode_-xfPNnkGge

BTW, the example simulation is loosely based on your original circuit but I did not fully undertsand what your original circuit was intended to do, there are some differences such as how the photodiode is connected and the R and C component values between the SPDT switched feedback paths.

:)

i tried the demo circuit of photo diode that you have given but i get some errors in that i don't understand why these errors are coming
the errors are

Circuit: untitled

Error: unknown subckt: xd1 volprobe1 xd1_k xd1_3 photodiode_ee
https://easyeda.com/editor#id=Qc0A9vtrp|8sqoJjTtr
here is a link for that

Oops.

I had set some text to be a spice directive instead of comment.

Fixed it now.

Sorry about that.

:)

still i get same errors
Error: unknown subckt: xd1 volprobe1 xd1_k xd1_3 photodiode_ee
https://easyeda.com/editor#id=8sqoJjTtr
plz look at this link tell me about the errors

Virajsawant131,

Sorry but the links you have posted are not to public files so I can't see them.

Can you make them public?

Can you run my example files in:

https://easyeda.com/andyfierman/Demonstrating_the_EasyEDA_generic_photodiode_-xfPNnkGge

?

https://easyeda.com/editor#id=mcMlVvtrp

You have to set the .subckt text to be "active" spice statements. At present they are "inactive" comment text.

Select the text then set Text type > spice in the right hand Text Attributes panel.

I strongly advise that you look through - and play with the examples in - the EasyEDA Simulation eBook:

https://docs.google.com/document/u/1/d/1OWZVVFRAe_2NW3WratpkA_SGuHa5AcRow5ZRfvcoVTU/pub

In particular see:

Advanced probing and simulation control

https://docs.google.com/document/u/1/d/1OWZVVFRAe_2NW3WratpkA_SGuHa5AcRow5ZRfvcoVTU/pub#h.4i7ojhp

and:

Device models

https://docs.google.com/document/u/1/d/1OWZVVFRAe_2NW3WratpkA_SGuHa5AcRow5ZRfvcoVTU/pub#h.43ky6rz

(The Google link above is to the original copy of the Simulation eBook which you can also find at:

https://easyeda.com/Doc/Simulation-eBook/

but the table of contents in the EasyEDA copy is broken and misses out some sections. We are working to fix it but in the meanwhile the copy published to the web from Google Drive works just as well.)

is there spice model available for AD8271

http://www.analog.com/en/products/amplifiers/specialty-amplifiers/difference-amplifiers/ad8271.html#product-overview here is the link for the circuit which i want to simulate the lock in amplifier

https://easyeda.com/editor#id=tS0TN5BTN here is the link for the circuit
i got some errors in the simulation.

1. There is no model for the AD8271 but there is a model for the dual channel AD8270:

http://www.analog.com/media/en/simulation-models/spice-models/AD8270.cir

If you have problems getting this model to run, please post back.

2. For:

https://easyeda.com/editor#id=tS0TN5BTN

please check the simulation results window. The error message at the bottom of the window is telling you that the problem is that the optical_input_power netlabel is not attached to the wire from the + end of V1. Move the netlable onto the wire and the circuit will run.

:)

There are now models and spice symbols for the AD8271 and the AD8270_DUAL in the SHIFT+F searcheable library.

:)

.subckt PHOTODIODE_EE A K PHOTONIP
Rseries A Aint 100m
Bdiode K Aint I=V(PHOTONIP)0.010.6
Cdiode K Aint 1p
Rdiode K Aint 1G
Dideal Aint K D
Rphotonip PHOTONIP 0 1G
.model D D()
.ends PHOTODIODE_EE
can you please tell me what are these parameters Bdiode K Aint I=V(PHOTONIP)0.010.6 and Rphotonip PHOTONIP 0 1G

I have updated the model to clarify:

**********************************************
* EasyEDA generic photodiode subckt model
* Developed for EasyEDA 
* by signality.co.uk 160808
*
* PHOTONIP pin represents the optical 
* power input to the photodiode.
* It is a voltage input, referenced to 
* ground and scaled such that 1V = 1W 
* of optical input power.
*
* Bdiode generates photocurrent in response 
* to voltage input at PHOTONIP
*
* For info on photodiodes see:
* http://www.pacer.co.uk/Assets/Pacer/User/Photodiodes.pdf
* https://en.wikipedia.org/wiki/Photodiode
* http://www.hamamatsu.com/resources/pdf/ssd/e02_handbook_si_photodiode.pdf
* http://www.hamamatsu.com/us/en/product/category/3100/4001/4103/index.html
**
*
.subckt PHOTODIODE_EE A K PHOTONIP
.param Resp = 0.38 ; A/W. Typical Responsivity of silicon photodiode.
Rseries A Aint 100m ; Ohms. 
Bdiode K Aint I=V(PHOTONIP)*Resp
Cdiode K Aint 1p
Rdiode K Aint 1G
Dideal Aint K D
Rphotonip PHOTONIP 0 1G ; DC path to ground for PHOTONIP input.
.model D D()
.ends PHOTODIODE_EE
**********************************************

I have also removed the factor of 0.01 in the expression for Bdiode since this was a mistake left over from the phototransitor model from which the phot0diode model was extracted.

For further information on photodiode modelling please see the links given in the model itself.

:)

if i want to change this model by using different parameters,so how can i make that model to use in my circuit.

This is explained in the Device models section - including the examples - in the tutorial that I pointed you to in one of my earlier posts:

https://docs.google.com/document/u/1/d/1OWZVVFRAe_2NW3WratpkA_SGuHa5AcRow5ZRfvcoVTU/pub#h.43ky6rz

(The Google link above is to the original copy of the Simulation eBook which you can also find at:

https://easyeda.com/Doc/Simulation-eBook/

but the table of contents in the EasyEDA copy is broken and misses out some sections. We are working to fix it but in the meanwhile the copy published to the web from Google Drive works just as well.)

Thanks.

In case you're still struggling with this, all you have to do is copy and paste the original .subckt from the netlist, paste it into your schematic, edit the parameters, change the .subckt and the symbol name in the schematic to something like MY_PHOTODIODE_EE and then set the text type of the pasted-in netlist from comment to spice.

Done.

is there spice model available for ADG733

here is the link for the circuit https://easyeda.com/editor#id=DJVTQO0Yk

There is no ADG733 spice model available from AD.

I suggest you just use the basic EasyEDA voltage controlled switch (as in the Normally ON and Normall OFF switches on the left of your schematic).

If you need to you could make up the enable logic using the EasyEDA Libs basic logic gates.

See:

https://easyeda.com/example/Easy_logic_device_simulation_in_V2_3_x_onwards-RaKIG2oJ5

for more.

is there spice model available for ad7798/ad7799

i run the simulation by using voltage controlled switches that you suggested in case of ad733 but i did not get output which i expected it is slightly lower than this.the output that i required is 3.75V dc but it shows different. here is the link for the circuit https://easyeda.com/editor#id=D3XRxPJDU|DJVTQO0Yk
and another one is that can you please tell me how to make one switch one and another switch off in initial state.

is there spice model available for ad7798/ad7799

There are no spice models for these particular devices.

To understand why there are no ADC models in EasyEDA and in spice in general, please see this post:

https://easyeda.com/forum/topic/ADC_modells-7x3lfxP7o

i run the simulation by using voltage controlled switches that you suggested in case of ad733 but i did not get output which i expected it is slightly lower than this.the output that i required is 3.75V dc but it shows different.

Sorry but

1. your simulation does not seem to run (it times out) and;

2. your circuit is too complicated to just give a simple amswer to this question. You'll need to provide an explanation of what your circuit is supposed to be doing, what the switch control voltages are set to, where you are expecting to see this 3.75V and why you expect to see it.

can you please tell me how to make one switch one and another switch off in initial state.

There is already an example of this in the Normally ON and Normally OFF switches on the left of your schematic.

More info:

The Voltage Controlled switches are controlled by the input voltage. They hard switch between the finite Ron and Roff resistance values. They do not have any linear or slew rate limited regions between these two resistances.

Ron must be > 0.

Roff must be > 0 and finite.

(In fact, resistances can be negative but it is not recommended to try this unless you understand exactly the consequences of using negative resistance values!)

They have a threshold voltage, VT, below which they are in the 'OFF' state and above which they are in the 'ON' state.

It is important to understand that the resistance in each of these states is independent of the actual state so the ON state resistance (Ron) can be high or low. Similarly the OFF state resistance (Roff) can also be high or low.

They can also have a hysteresis, VH, which is any positive value including zero. VH = 0 causes the switch to change state at exactly the value of VT. A positive value of VH causes the switch to turn 'ON' at VT+VH and 'OFF at VT-VH.

Switches with hysteresis can also be specified to be in a OFF or and ON initial state for an input voltage that is anywhere between the hysteresis range.

Note that current controlled switches behave in the same way but using a controlling current rather than a voltage.

These possibilities are illustrated in this simulation:

https://easyeda.com/andyfierman/Setting_up_switches-oW8SPbxTf

• For complete documentation of how the Voltage Controlled switches operate please see:

http://ngspice.sourceforge.net/docs/ngspice-manual.pdf#subsection.3.2.14

http://ngspice.sourceforge.net/docs/ngspice-manual.pdf#subsection.3.2.15

Is the intended function of S3, S4, S5, S6 - controlled by V9 - and U3 to form some sort of synchronous rectifier?

Maybe the server was very busy last night: for whatever reason, your sim runs OK this morning.

:)

However, note that you cannot run the AD8615 from a +/-5V supply. Abs max supply voltage across the device is 6V!

:(

Also please note that V9 is only switching between 0V and +1mV so it is not changing the state of S3, S4, S5 and S6.

• If you require help with the design of your circuit, please contact support to make a request for design support/review.
• However, please be aware that, depending on the complexity of your design and the level of support needed, there may be a charge for such supporting services.

Thanks.

so what should i do to change the state of S3,S4,S5,S9

You have not described what you want the switches to do, however, if you look in the right hand panel you will find the switch parameters.

Please study my description and the example I posted above (and the further information in the ngspice manual if you need) to set these and or the controlling voltage source parameters to control the switches (and you may need to add more sources to get all your switches to do what you want).

Here's how to find (and where to adjust) the switch parameters in the right hand panel:

Just select the switch and then edit the values.

the option for run the simulation is not showing
please help me

the option for run the simulation is not showing

Please see:

https://easyeda.com/forum/topic/Run_Simulation_button_missing-UomWvRPNL

i am getting some error like v1:no dc value transient time 0 exit while running simulation i don't understand what does actually mean please help me
here is a link for that https://easyeda.com/editor#id=5df260e456834033a45bffbdeaacef10

and the circuit represents ac coupling which i want to do simulation

sorry the link ishttps://easyeda.com/editor#id=35d3beaddc7246ac8b2710c08386bfdb

https://easyeda.com/editor#id=35d3beaddc7246ac8b2710c08386bfdb

Please re-read the section in the EasyEDA Simulation eBook and look very carefully at the examples:

Device models

https://docs.google.com/document/u/1/d/1OWZVVFRAe_2NW3WratpkA_SGuHa5AcRow5ZRfvcoVTU/pub#h.43ky6rz

(The Google link above is to the original copy of the Simulation eBook which you can also find at:

https://easyeda.com/Doc/Simulation-eBook/

but the table of contents in the EasyEDA copy is broken and misses out some sections. We are working to fix it but in the meanwhile the copy published to the web from Google Drive works just as well.)

The error in your sim is that you have picked an non-simulation opamp symbol (it is intended only to be used for a non-simulation schematic: it has no spice model associated with it and does not have a suitable spice prefix (of X in this case)).

The simplest way to use a pasted-in opamp model is simply to place the 5 pin opamp symbol from the EasyEDA libs and then change the name to be exactly the same as that of the subckt you wish to associate with it.

In fact it is even simpler than that because I have already put a model for the AD8615 into the library so you don't even need to paste in the netlist!

That said, there appears to be a problem with the AD model because it seems to oscillate in your circuit for inputs above the positive supply rail (which is what your AC coupled input and DC biasing does).

Checking the model in another simulator shows that it appears to be a problem with the AD model and not our usage of it.

The model recovers when the input drops below the rail but by that time (especially with the 22u input cap you have set, which is suspect should have been 0.22u) the sim has hit the limit of the number of data points it can run to (this is to prevent people spamming EasyEDA with huge long simulations).

The work around is to set your AC coupled input signal and the input DC biasing so that the input to the opamp never exceeds the VCC rail.

:)

hi andy
please help me with this error

Circuit: gooduntitled

Doing analysis at TEMP = 27.000000 and TNOM = 27.000000

Warning: singular matrix: check nodes ct_1 and ct_1

Note: Starting dynamic gmin stepping
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Warning: singular matrix: check nodes ct_1 and ct_1

Warning: Dynamic gmin stepping failed
Note: Starting source stepping
Warning: singular matrix: check nodes ct_1 and ct_1

Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful source step
Warning: singular matrix: check nodes ct_1 and ct_1

Warning: singular matrix: check nodes ct_1 and ct_1

Warning: source stepping failed

Transient solution failed -

Last Node Voltages

Node Last Voltage Previous Iter

xd1_1 1.23621e-89 1.53785e-101
volprobe1 -2.74367e-88 -2.07671e-97
xd1.3 -2.74367e-88 0
v1_+ 0 0
rsc_2 1.55704e-92 0
rno_1 1.23621e-89 0
u1_5 -6.85919e-89 0
ct_1 0 0
l1#branch -6.85919e-92 0
v1#branch 6.85919e-92 0
v.xd1.vz#branch 5.07818e-96 0

doAnalyses: iteration limit reached

tran simulation(s) aborted
Error(parse.c--checkvalid): volprobe1: no such vector.
ngspice-26 done
my schematic link is
https://easyeda.com/editor#id=11a9ce2491eb4a84b547354bb8deed87
please help

Sorry Looli but your schematic is not public:

https://easyeda.com/Doc/Tutorial/share.htm#Sharing

hi Andy
I made it public see if its opening or not
https://easyeda.com/editor#id=9529539335494c7e9f52281dbac8bec8
and here is the error
Circuit: good* no system model for voltmeter, you can create a model by yourself

Doing analysis at TEMP = 27.000000 and TNOM = 27.000000

Warning: singular matrix: check nodes u1_3 and u1_3

Note: Starting dynamic gmin stepping
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Warning: singular matrix: check nodes u1_3 and u1_3

Warning: Dynamic gmin stepping failed
Note: Starting source stepping
Warning: singular matrix: check nodes u1_3 and u1_3

Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful gmin step
Note: One successful source step
Warning: singular matrix: check nodes u1_3 and u1_3

Warning: singular matrix: check nodes u1_3 and u1_3

Warning: source stepping failed

Transient solution failed -

Last Node Voltages

Node Last Voltage Previous Iter

u1_1 1.80655e-56 9.68929e-70
xd1_2 -2.16777e-64 -1.30805e-65
xd1.3 -2.16777e-64 0
xvm1_2 0 0
c1_1 0 0
u1_7 1.80655e-56 0
r3_2 1.80655e-56 0
u1_5 -5.41942e-65 0
u1_3 0 0
l1#branch -1.80655e-68 0
v1#branch 0 0
v.xd1.vz#branch -1.80588e-68 0

doAnalyses: iteration limit reached

tran simulation(s) aborted
Error(parse.c--checkvalid): xd1_2: no such vector.
ngspice-26 done
please help

Hi Looli,

There is one major reason that your sim fails:

1. At the time you created this sim, there was no spice model for the MC34063 in the EasyEDA library. Therefore the sim fails because the model is missing.

I have now located a suitable model and built a spice symbol (both called MC34063) and put them in the library.

I have also added a spice model for the 1N5819 schottky diode.

There are however, some other problems with it:

2. D1 is a zener diode and not a schottky diode.

3. There's a mistake in your schematic in that there's a connection missing between battery + and U1 pin 7.

I have made a copy of your sim based on Fig 9 in:

http://www.onsemi.com/pub_link/Collateral/MC34063A-D.PDF

which shows the model in operation.

However, before proceeding much further, I recommend that you read - and play with the simulation examples in - the EasyEDA Simulation eBook:

https://docs.google.com/document/u/1/d/1OWZVVFRAe_2NW3WratpkA_SGuHa5AcRow5ZRfvcoVTU/pub

and also see:

https://easyeda.com/forum/topic/How_to_find_out_what_spice_models_are_available_in_EasyEDA_-ACUO5nhXf

Also, to save having to look down a very long thread, if you have further questions, please start a new thread.

Thanks.

The example is here:

https://easyeda.com/andyfierman/Looli-68dfa7888c6745a8a446dafdebd2b9d7

i got some error while running the simulation which i really do n0t understand why it is coming so please help me to solve this problem. here is link for my simulation . the simulation is about ac coupling.
https://easyeda.com/editor#id=e33103e1f96545059758d5ff82e7af0a

Simple problem.

You have not selected a symbol for the AD8615 that has a spice model associated with it.

Therefore no AD8615 is netlisted in the spice netlist.

Therefore it does not exist in your simulation.

To fix this, place a 5 pin op amp symbol from the EasyEDA Libs:

then change the name from UA741 to AD8615.

Please revisit the advice from one of my earlier emails:

I strongly advise that you look through - and play with the examples in - the EasyEDA Simulation eBook:

https://docs.google.com/document/u/1/d/1OWZVVFRAe_2NW3WratpkA_SGuHa5AcRow5ZRfvcoVTU/pub

In particular see:

: 

: 

: 

:
 
Device models

https://docs.google.com/document/u/1/d/1OWZVVFRAe_2NW3WratpkA_SGuHa5AcRow5ZRfvcoVTU/pub#h.43ky6rz

(The Google link above is to the original copy of the Simulation eBook which you can also find at:

https://easyeda.com/Doc/Simulation-eBook/

but the table of contents in the EasyEDA copy is broken and misses out some sections. We are working to fix it but in the meanwhile the copy published to the web from Google Drive works just as well.)